BASIC プログラミング・文法・主なコマンド（命令文）

• BASIC(Beginner's All purpose Symbolic Instruction Code)は、1960年代、まだ「パーソナル・コンピュータ」などというものが存在していない時代にアメリカで開発された、教育研究用のプログラミング言語。
  日本では、1980年代、日本電気（NEC)のPC-8801シリーズという「パソコン」の登場とともに、「N88日本語BASIC」がその基本言語となったため、一世を風靡した。当時大型計算機での科学技術計算には「FORTRAN(Formula Translator)」という言語が用いられていたが、同様の文法構造を用いて、なおかつ簡便であったことから普及したのだろう。
  
  FORTRANにせよ、BASICにせよ、「シーケンシャル(sequencial)」な、つまり、一つながりの「流れ作業」を前提としている。
  人間が考え出すことだから当然なのだが、人間は「原則」として、一度に二つの本を読むことができない。しかも、横書きの本なら、上から順番に1行ずつ、読むしかない。機械も、同様に、与えられたデータを、上から順番に1行ずつ、そこに記された命令に従って、処理していくように考案された。
  
  Excelなどの表計算ソフトの「ワークシート」のように、面的な広がりを持ったデータを同時に処理できたり、MacやWindowsのように、いくつもの「窓」の中で、別々の処理が同時並行にできるように、コンピュータの性能が向上すると、古典的な「シーケンシャル処理」を前提としたBASIC言語などは、急速に意味を失った。
  
  だから、今日では、あまり実用的には用いられていない。しかし、どんなに「同時並行処理」ができるといったって、その一つ一つのユニットにおいては、やはり、上から下への「シーケンシャル処理」から離れることはできないはずだ。だから、その基本構造を学ぶことは、今日的にも意味がある。そんな意味もあって、高等学校の数学Bのプログラミングにも、したがって、大学入試センター試験の第6問にも、BASICが採用されているわけだ。どこの電気屋さんに行っても、Windows上で実行可能なBasicソフトなんか売ってない、どこの本屋さんに行っても、Basicのマニュアルなんか売ってない、にもかかわらず！
  
  なお、BASICの文法構造は、今日でも、その複雑さにおいてほとんど原形をとどめてはいないけれども、Visual Basicというプロ仕様のプログラミング言語の中に生きているし、その簡約版はVBA(Visual Basic for Applications)として、たとえば、Excelのワークシート上の定型処理をプログラム化する際に用いられる「マクロ」の言語として、Windowsに標準装備されているから、まったく「役に立たない」、というわけでもない。
  
  どこの電気屋さんに行っても、Windows上で実行可能なBasicソフトなんか売ってない、のだが、インターネット上で、無料配布してくれているやさしいおじさんがいた。 http://www2.cc.niigata-u.ac.jp/~takeuchi/tbasic/ 新潟大学のタケウチさん、という研究者なのだろう、その方の開発になる「Tiny Basic(ちっこいBasic)」、以下のサンプルプログラムの出力結果などは、このソフトを利用させていただいた。
  
  
• 入出力
  • INPUT [変数名]
    キーボードから入力された「値」を、「変数名」で名づけられたレジスターに格納する。
    実行画面では、「?」が表示される。
  • INPUT "[プロンプト・メッセージ]";[変数名]
    キーボードから入力された「値」を、「変数名」で名づけられたレジスターに格納する。
    「プロンプト・メッセージ(入力を促すメッセージ)」は、そのまま画面に表示される。複数の変数の入力が必要な場合、実行時に画面に「?」が出ただけでは、どんな変数の入力を求められているのかわからない。そこで、何を入力してほしいのかを案内するメッセージをつける。
  • PRINT [変数名]
    「変数名」レジスターの値を、画面に表示する。
  • PRINT [メッセージ]";[変数名]
    「メッセージ」部分は、そのまま画面に表示される。
  • 複数の変数に、同時に入出力することもできる。変数名をカンマ「,」でつなぐ。
    INPUT [変数名],[変数名],・・・・
    PRINT [変数名],[変数名],・・・・
    
    
  • 例文(sample01)
    100 INPUT "Aの値を入力してください";A
    110 PRINT "Aの値は";A
    120 END
    
    実行結果（「30」をキーボードから入力したとすると）
    
    

    Aの値を入力してください? 30 Aの値は30

    
    
  
  
  
• 代入文
  [変数名]=[値]
  
  プログラム言語では、=(等号)は数式の場合のように、左辺と右辺が等しいことを示すよりは、右辺の値を左辺の「変数」に「代入」する意味で用いられることのほうが多い。
  N=N+1 や S=S+A のように、数学的に意味のない式であっても、これらは、それぞれ、「Nという名前のレジスターの値を、それに1を加えた新しい値に書き換え、『上書き保存』する」、「Sという名前のレジスターの値を、それにAという名前のレジスターにある値を加算して、新しい値に書き換え、『上書き保存』する」、という命令を表している。
  これらは、後に述べる「ループ処理」の中で用いると、それぞれ、「ループ回数のカウンター」、「データの和を求める」という機能を担うことになる。
  
  LET [変数名]=[値]
  
  という書き方もある。
  100 X=3
  と、
  100 LET X=3
  は、まったく同じ意味である。だから、通常LET文は、使わない。
  
  
• 「文番号」
  BASIC言語では、すべてのコマンドに上から順に「文番号」が割り当てられる。「文番号」にしたがって、上から順番に処理を行うのが「原則」である。
  しかし、上から下へ1度きり流れてしまったら終わりというのなら、コンピュータのありがたみはさほどない。「飛び越し」、「条件による分岐」、「ループ（繰り返し処理）」などが、「文番号」による処理の流れの「例外」である。
  
  ところで、「文番号」が、突如100から始まったり、10ずつ増えたりしているのは、なぜでしょうか？
  それは、人間が、誤りを犯す生き物だからです。プログラマはプログラムを書くとき、たくさん失敗をします。後から、文と文の間に挿入したり、文を削除したり、順序を入れ替えたりしなくてはいけません。そんなとき、１きざみの番号だったら、全部書き直さなくてはならないでしょ？
  
  
• 「無条件飛び越し」(GOTO文)
  GOTO [文番号]
  
  指定された｢文番号｣へ無条件で移動する。文番号は、現在位置より小さくても大きくてもかまわない。
  現在位置より小さな文番号を指定すれば、後戻りすることになるから、これを使って｢ループ｣を作ることができる。
  
  
• ｢条件による分岐｣(IF〜THEN〜ELSE文)
  IF [条件式] THEN [条件を満たす時の処理] ELSE　[条件を満たさない時の処理]
  
  ELSE以下は省略することが多い。その時は文番号の原則に従い、次の文に移行する。
  次のような表記法もある。
  
  IF [条件式] THEN
  [条件を満たす時の処理]
  ・・・・
  ELSE
  [条件を満たさない時の処理]
  ・・・・
  END IF
  
  それぞれの「処理」がいくつもあるときには、この表記法のほうがわかりやすい。
  
  

  条件式の文法
  =	等しい
  >	より大きい
  <	より小さい
  >=	以上
  <=	以下
  <>	等しくない

  
  
  
  • 例文(sample02)
    100 INPUT N
    110 I=0
    120 I=I+1
    130 IF I>N THEN GOTO 160
    140 PRINT I
    150 GOTO 120
    160 END
    
    これは、以下のように書いても、同じだ。
    
    100 INPUT N
    110 I=0
    120 I=I+1
    130 IF I>N THEN
    132 GOTO 160
    134 END IF
    140 PRINT I
    150 GOTO 120
    160 END
    
    実行結果（「5」をキーボードから入力したとすると）
    
    

    ? 5 1 2 3 4 5

  
  
  
• ループ（繰り返し処理）
  上の例文のように、GOTO文と、IF〜THEN〜ELSE文を組み合わせるほかに、FOR〜NEXT文によっても、ループを作ることができる。
  
  FOR [ループ制御変数]=[初期値] TO [終了値]
  ・・・・・
  （繰り返し処理）
  ・・・・・
  NEXT [ループ制御変数]
  
  FORの後ろに置かれた変数が、「ループ」回数を制御する変数である。NEXT文にくるたびにこの変数に1が加えられ、FOR文に戻る。ループ制御変数の値が「終了値」を超えると、「繰り返し処理」を行わず、NEXT文の次の行に移る。
  
  
  • 例文(sample03)
    100 INPUT N
    110 FOR I=1 TO N
    120 PRINT I
    130 NEXT I
    140 END
    
    実行結果は、sample02の場合とまったく同じになる。
  
  
  
• 演算記号と「組込み関数」
  
  

  演算記号
  +	たす
  -	ひく
  *	かける
  /	割る
  ＾	べき乗

  
  
  関数は、y=f(x)のように表現できる。xを「引数」と呼ぶ。「引数」に何を代入しても同じ答えを返してくる関数の場合は、引数を()で省略する。BASICのプログラム上で「関数」を定義することも、もちろんできるが、三角関数・対数など、しばしば使われる関数は、ほとんどが、あらかじめ組み込まれている。これを「組込み関数」と呼ぶ。

  組込み関数
  PI()	円周率π
  INT([数式])	小数点以下切り捨て、整数化(Integer:整数)
  SQR([数式])	正の平方根(Square Root:平方根)
  SIN([数式]),COS([数式]),TAN([数式])	sin,cos,tan

  
  
  INT関数には、いくつかの面白い使い方がある。
  
  
  • 例文(sample04)
    100 INPUT N
    110 PRINT PI()*N
    120 PRINT INT(PI()*N*100)/100
    130 PRINT SQR(N)
    140 PRINT INT(SQR(N)*100)/100
    150 PRINT SIN(PI()*N/3)
    160 PRINT INT(SIN(PI()*N/3)*100)/100
    170 END
    
    110行では、入力されたnに対して、nπの値を計算させている。ところが、小数点以下が長すぎるので、これを、小数第2位までで「切捨て」るには、120行のような「小ワザ」を使う。いったん100倍して、INT関数を利用して、切捨て整数化し、再び100で割るのだ。
    
    140行、160行でも同様に、それぞれ、√n、Sin(nπ/3)の値を、小数第2位まで切捨てで、表示させている。
    
    実行結果（「2」をキーボードから入力したとすると）
    
    

    ? 2 6.28318530717958648 6.28 1.41421356237309505 1.41 0.866025403784438647 0.86

    
    では、「四捨五入」というもう少し高度な判断が必要な操作は、どう表現したらいいだろう？
    
    
  • 例文(sample05)
    100 INPUT N
    105 PRINT SQR(N)
    110 A=SQR(N)*100
    120 PRINT INT(A)/100
    130 B=A-INT(A)
    140 IF B>=0.5 THEN A=A+1
    150 PRINT INT(A)/100
    160 END
    
    入力されたnに対して、√nの値を、105行では、そのまま、120行では小数点以下二桁で切り捨て、そして、150行では、小数点以下第3位を「四捨五入」して、表示する。真の値と、100倍して小数点以下切捨て整数化した値との差が「0.5以上かどうか」という「条件判断」をIF文を使って行っているのだ。
    
    実行結果（「5」をキーボードから入力したとすると）
    
    

    ? 5 2.2360679774997897 2.23 2.24

    
    
    
  • ある整数が、それより小さいある整数を因数に持つかどうかを判定するプログラム(sample06)
    110 INPUT "割られる数";N
    120 INPUT "割る数";M
    130 IF M<=N THEN GOTO 140
    135 PRINT "割る数が、割られる数より大きい"
    137 GOTO 120
    140 D=N-INT(N/M)*M
    150 IF D=0 THEN GOTO 180
    160 PRINT "割り切れません"
    170 GOTO 190
    180 PRINT "割り切れます"
    190 END
    
    140行の変数Dは、整数Nを整数Mで割った「余り」を表している。
    135行は（文番号が半端な数になっているのは、後から付け加えたからだ）、不適当な入力に対するエラーメッセージである。
    
    実行結果
    
    

    割られる数?8 割る数?21 割る数が、割られる数より大きい 割る数?3 割り切れません

  
  
  
• 終了文
  END
  プログラムが終了したことを表す。
  なくてもエラーにはならないんだけど・・・。
  
  

応用編

• センターテスト1997年(sample07)
  10 INPUT "N=";N
  20 FOR I=1 TO N
  30      J=I*I
  40      K=N-J
  50      PRINT "K=";K
  60      IF K=<0 THEN GOTO 80
  70 NEXT I
  80 IF K<0 THEN GOTO 110
  90 PRINT "YES ";N;" = ";I;" * ";I
  100 GOTO 120
  110 PRINT "NO"
  120 END
  
  プログラムを見ても何をしているのかわからないときは、とりあえず、「自分が（きわめて低級な）コンピュータになった」気持ちで、変数レジスターの内容がどう書き換えられていくかの過程を、書き出してみるといい。
  
  このプログラムに登場する変数は、上から順番にN,I,J,Kである。その内容が、どう書き換えられていくかを、下の表でたどってみる。
  
  N=?に対して21を入力した場合。

  N	I	J	K	画面の表示
  21	1	1	20	K=20
  21	2	4	17	K=17
  21	3	9	12	K=12
  21	4	16	5	K=5
  21	5	25	-4	K=-4 NO

  
  
  N=?に対して25を入力した場合。

  N	I	J	K	画面の表示
  25	1	1	24	K=24
  25	2	4	21	K=21
  25	3	9	16	K=16
  25	4	16	9	K=9
  25	5	25	0	K=0 YES 25 = 5 * 5

  
  
  こうして、このプログラムが、入力された整数が、平方数であるかどうかを判定するプログラムであることが、わかった。
  
  

  ---

  
  
• 2変量の、平均、標準偏差、相関係数を求めるプログラム(sample08)
  100 SX=0
  110 SXX=0
  120 SY=0
  130 SYY=0
  140 SXY=0
  150 INPUT "データの個数";N
  160 FOR I=1 TO N
  170      INPUT "データ(x,y)";X,Y
  180      SX=SX+X
  190      SY=SY+Y
  200      SXX=SXX+X*X
  210      SYY=SYY+Y*Y
  220      SXY=SXY+X*Y
  230 NEXT I
  240 MX=SX/N
  250 MY=SY/N
  260 VX=SXX/N-MX*MX
  270 VY=SYY/N-MY*MY
  280 SIGMAXY=SXY/N-MX*MY
  290 SIGMAX=SQR(VX)
  300 SIGMAY=SQR(VY)
  310 R=SIGMAXY/(SIGMAX*SIGMAY)
  320 PRINT "xの平均";INT(MX*100)/100,"yの平均";INT(MY*100)/100
  330 PRINT "xの標準偏差";INT(SIGMAX*100)/100,"yの標準偏差";INT(SIGMAY*100)/100
  340 PRINT "x,yの相関係数";INT(R*100)/100
  350 END
  
  SXは変量xの和、SYは変量yの和、SXXは変量xの2乗の和、SYYは変量yの2乗の和、SXYは変量x,yの積の和、である。
  100行から、140行では、これらの値をあらかじめ「ゼロクリア」・「初期値設定」している。こんなことをしなくても、初めて定義された変数レジスターの中身は0に決まっているのだが、これはある種プログラマの身についた習慣であって、多人数でプログラムを共同開発する場合は、同じ変数名をほかの人がどこかで使っているかもしれない、そうだとすると0でない何らかの値がそこに残されているかもしれない、と気遣っての安全策だ。
  
  160行〜230行のFOR〜NEXTループで、変量x,yの入力を行っている。ここで、ぜひとも注目していただきたいのは、入力された「元データ」はこのプログラム上のどのレジスターにも、残されていないことだ。170行のINPUT文を通過するたびに、変数X,Yのレジスターは、新たに入力されたデータに書き換えられる。
  ここにこそ、「シーケンシャル」なデータ処理の決定的な弱点でもあり、同時にものすごい「汎用性」を持ちうる根拠がある。このプログラムで、「データの個数?」に対して1000000と答えれば、100万個のデータ処理が可能なのだ。100万回(x,y)のデータのペアを、手で入力する、とか、もしミスをしたら最初からやり直す、とかいう非現実的な部分を度外視すれば、原理的には可能なのだ。このプログラムの実行が終了した段階で、その100万個のデータは、どこにも残っていない、残っていないにもかかわらす、その標準偏差や、相関係数は、ちゃんと計算できている。
  
  Excelのような「多元処理」が可能なソフトウェアで同じことをしたとすれば、x,yあわせて200万個の「セル」に「元データ」をすべて残すことができる。200万個の「セル」というのは、どのくらいの広さになるのだろう？６畳一間では足りないかもしれない。メモリの状態にもよろうが、たぶん、またしても、原理的には、可能だ。そうして、1000001行目のセルで合計を計算し、その下のセルで平均を計算し、という風に、下に示したワークシートのサンプルのようにして、標準偏差や相関係数が苦もなく計算できる。
  だが、200万個のセルの内容を「保存」するのには、ものすごくたくさんの「記憶素子」という「資源(resource)」が必要なのだ。Basicの時代のコンピュータには、それができなかった。今はできるようになった。だから、「よい」のか？って問題だ。
  データのというのは、多ければ多いほどよい、ってわけ『ぢゃ』ない、という「情報理論のアポリア（難問）」を少しでも、感得して頂けただろうか？
  
  さらに、このような「シーケンシャル処理」を前提とする限り、なぜ、「分散」や「共分散」の定義式、
  

  「分散」		「偏差」の2乗の平均
  「共分散」		「偏差」の積の平均

  が、「役に立たず」、実用式、
  

  「分散」		「2乗の平均」−「平均の2乗」
  「共分散」		「積の平均」−「平均の積」

  でなければならないのか、の理由も、理解していただけると思います。Excelならば、どちらもたいした違いはありません。だが、Basicで、「定義式」に基づいたプログラムを組んでみることを想像してください。
  x_iが入力された段階で、すでにxの平均値xが計算されていないといけないんですよ。ということは、160行から230行のFOR〜NEXTループを2回まわして、もう一度データを入力するか、もしくは、入力データを、どこかに、「格納」しておかなければならないのです。データの個数もあらかじめはわからないときに、すべてのデータを格納する変数名を決めることさえ困難です。
  
  実行結果
  
  

  データの個数?5 データ(x,y)?3,7 データ(x,y)?4,9 データ(x,y)?5,10 データ(x,y)?4,8 データ(x,y)?4,6 xの平均 4 yの平均 8 xの標準偏差 0.63 yの標準偏差 1.41 x,yの相関係数 0.67

  
  同じことをExcelで計算した結果を下に示す。
  
  

  ---

  
  
• センターテスト2005年追試験数学�TA
  
  
  
  (3)の変更前のプログラム(sample18)
  100 INPUT "N=";N
  110 INPUT "P=";p
  120 A=0
  130 X=INT(N/P)
  140 Y=N-P*X
  150 PRINT Y;
  160 A=A+1
  170 N=X
  180 IF N>0 THEN GOTO 130
  190 PRINT ";"
  200 PRINT A
  210 END
  
  
  N=?に2006、P=?に10を入力したときの変数レジスター内容の変化

  N	P	A	X	Y	画面の表示
  2006	10	0	200	6	6
  200	10	1	20	0	0
  20	10	2	2	0	0
  2	10	3	0	2	2
  0	10	4			;4

  
  
  実行結果

  6   0   0   2; 4

  
  
  N=?に99、P=?に4を入力したときの変数レジスター内容の変化

  N	P	A	X	Y	画面の表示
  99	4	0	24	3	3
  24	4	1	6	0	0
  6	4	2	1	2	2
  1	4	3	0	1	1
  0	4	4			;4

  
  
  実行結果

  3   0   2   1; 4

  
  
  
  
  
  
  
  
  (3)の変更後のプログラム(sample19)
  100 INPUT "N=";N
  110 INPUT "P=";p
  120 A=0
  130 X=INT(N/P)
  140 Y=N-P*X
  150 PRINT Y;
  160 A=A+1
  170 N=X
  180 IF Y=0 THEN GOTO 130
  190 PRINT ";"
  200 PRINT A
  210 END
  
  
  N=?に120、P=?に2を入力したときの変数レジスター内容の変化

  N	P	A	X	Y	画面の表示
  120	2	0	60	0	0
  60	2	1	30	0	0
  30	2	2	15	0	0
  15	2	3	7	1	1
  7	2	4			;4

  
  
  実行結果

  0   0   0   1; 4

[問題集]
1. 
   
2. 
   
3. 
   
   
   

• 商と余を求めるプログラム(sample13)
  10 INPUT "割られる数";A
  15 INPUT "割る数";B
  20 PRINT "商:Q=";INT(A/B)," 余:R=";A-(INT(A/B)*B)
  30 END
  
  
  
• 入力したデータの最大値・最小値を求めるプログラム(sample09)
  10 INPUT "NUMBER OF DATA";N
  20 K=0
  30 K=K+1
  40 IF K>N THEN GOTO 130
  50 PRINT "DATA NO.",K
  60 INPUT D
  70 IF K<>1 THEN GOTO 100
  80 DMAX=D
  90 DMIN=D
  100 IF D>DMAX THEN DMAX=D
  110 IF D<DMIN THEN DMIN=D
  120 GOTO 30
  130 PRINT "MAX=";DMAX, "MIN=";DMIN
  140 END
  
  
  
• 入力した数の階乗を求めるプログラム(sample11)
  10 N=0
  20 X=1
  30 INPUT N
  40 FOR K=1 TO N
  50 X=X*K
  60 NEXT K
  70 PRINT X
  80 END
  
  
  
• nとrを入力し、順列・組み合わせを求めるプログラム(sample10)
  10 N=0
  20 INPUT "N=";N
  30 INPUT "R=";R
  40 X=N
  50 FOR K=1 TO R-1
  60 X=X*(N-K)
  70 NEXT K
  80 PRINT "nPr=";X
  90 D=1
  100 FOR K=1 TO R
  110 D=D*K
  120 NEXT K
  130 PRINT "nCr=";X/D
  140 END
  
  
  
• 素数判定プログラム(sample12)
  10 I=0
  20 INPUT N
  30 FOR K=2 TO N-1
  40 R=N-(INT(N/K)*K)
  50 IF R<>0 THEN GOTO 80
  60 I=I+1
  70 PRINT I,K
  80 NEXT K
  90 IF I=0 THEN PRINT "素数"
  100 END
  
  
  
• センターテスト2000年追試験数�TA・その1(sample20)
  130 INPUT "J="=;J
  140 S=0
  150 FOR K=1 TO J
  160      S=S+(2*K-1)
  170 NEXT K
  180 PRINT S
  220 END
  
  
  
• センターテスト2000年追試験数�TA・その2(sample21)
  110 INPUT "N=";N
  120 T=0
  130 FOR J=1 TO N
  140      S=0
  150      FOR K=1 TO J
  160          S=S+(2*K-1)
  170      NEXT K
  180      PRINT S;
  190      T=T+S
  200 NEXT J
  210 PRINT T
  220 END
  
  
  
• センターテスト2005年本試験数�TA(sample16)
  100 INPUT "N=";N
  110 IF N>9 THEN GOTO 230
  120 FOR A=1 TO N
  130      FOR B=1 TO N
  140        IF B=2*INT(B/2) THEN GOTO 210
  150        IF B=A THEN GOTO 210
  160            FOR C=1 TO N
  170                IF C=A THEN GOTO 200
  180                IF C=B THEN GOTO 200
  190                PRINT 100*A+10*B+C
  200            NEXT C
  210          NEXT B
  220        NEXT A
  230 END
  
  
  
• センターテスト2005年本試験数�TA・変更後(sample17)
  100 INPUT "N=";N
  110 IF N>9 THEN GOTO 230
  120 FOR A=1 TO N
  130      FOR B=1 TO N
  140        IF B=2*INT(B/2) THEN GOTO 210
  150        IF B=A THEN GOTO 210
  160            FOR C=B TO N
  170                IF C=A THEN GOTO 200
  180                IF C=B*INT(C/B) THEN GOTO 200
  190                PRINT 100*A+10*B+C
  200            NEXT C
  210          NEXT B
  220        NEXT A
  230 END
  
  
  
• センターテスト2006年数�UB(sample14)
  100 INPUT "n=";N
  110 LET I=2
  120 IF N-INT(N/I)*I<>0 THEN
  130      LET I=I+1
  140      GOTO 120
  150 END IF
  160 LET N=N/I
  170 IF N=1 THEN
  180      PRINT I
  190      GOTO 230
  200 END IF
  210 PRINT I;"*";
  220 GOTO 120
  230 END
  
  
  
• センターテスト2006年数�UB・変更後(sample15)
  100 INPUT "n=";N
  110 LET I=2
  120 IF N-INT(N/I)*I<>0 THEN
  130      LET I=I+1
  140      GOTO 120
  150 END IF
  161 IF N-INT(N/I)*I=0 THEN
  162      LET N=N/I
  163      GOTO 161
  164 END IF
  170 IF N=1 THEN
  180      PRINT I
  190      GOTO 230
  200 END IF
  210 PRINT I;",";
  220 GOTO 120
  230 END